Windows服务器/VPS教程：如何修改3389端口来升级安全性能

一般我们用户选择的 VPS、服务器安装 LiNUX 系统会默认 22 端口，而Windows系统一般默认3389端口，也有一些服务商会设置固定或者随机的其他端口。从安全角度看，我们在设置服务器安全的时候，需要将默认端口修改，至少可以确保一些软件自动的扫描行为。

下面我们介绍两种修改方法，一种是手工修改注册表，另一种是用批处理文件自动修改。

手动修改注册表方法

点击开始–运行–输入 regedit 进入注册表编辑界面：

根据很多教程我们需要一步步进入文件夹中，然后找到

（HKEY_LOCAL_MACHINE\System\CurrentControlSet\Control\Terminal Server\WinStatiONs\RDP-Tcp）

或者直接在编辑–查找，PortNumber 字符也可以；

然后修改默认 3389 端口

这里默认是在十六进制中，看到的不是数字，这里我们选择十进制就可以看到数字。然后修改自己需要的端口保存。

最后，重启服务器生效，我们就可以用新端口登入。当然修改端口仅仅是简单的安全因素，其他包括软件的安全，以及其他安全手段也是需要注意的。

自动批处理修改注册表方法

把下面的代码另存为 3389.bat 然后双击运行：

@echo off
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
if '%errorlevel%' NEQ '0' (
goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
exit /B
:gotAdmin
if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
title 修改远程端口与用户密码
mode con: cols=55 lines=10
color 17
set "ing=ping -n 5 127.0.0.1 > nul"
:Menu
cls
echo ==============================
echo.
echo 1.修改远程端口
echo.
echo 2.修改用户密码
echo.
echo 3.重启计算机
echo.
echo ==============================
choice /C:123 /N /M "请输入你的选项 [1,2,3]"：
if errorlevel 3 goto:Restart
if errorlevel 2 goto:Password
if errorlevel 1 goto:RemotePort
:RemotePort
cls
set /P "Port=自定义远程桌面端口(1-65535): "
if %Port% leq 65535 (
Reg add "HKLM\SYSTEM\CurrentControlSet\Control\Terminal Server\Wds\rdpwd\Tds\tcp" /v "PortNumber" /t REG_DWORD /d "%Port%" /f  > nul
Reg add "HKLM\SYSTEM\CurrentControlSet\Control\Terminal Server\WinStations\RDP-Tcp" /v "PortNumber" /t REG_DWORD /d "%Port%" /f  > nul
Reg add "HKLM\SYSTEM\CurrentControlSet\Services\SharedAccess\Parameters\FirewallPolicy\FirewallRules" /v "{338933891-3389-3389-3389-338933893389}" /t REG_SZ /d "v2.29|Action=Allow|Active=TRUE|Dir=In|Protocol=6|LPort=%Port%|Name=Remote Desktop(TCP-In)|" /f > nul
Reg add "HKLM\SYSTEM\CurrentControlSet\Services\SharedAccess\Parameters\FirewallPolicy\FirewallRules" /v "{338933892-3389-3389-3389-338933893389}" /t REG_SZ /d "v2.29|Action=Allow|Active=TRUE|Dir=In|Protocol=17|LPort=%Port%|Name=Remote Desktop(UDP-In)|" /f > nul
echo 修改成功
echo 请牢记，你的远程端口是: %Port% 
echo 重启计算机生效
%ing% && goto:Menu) else (echo 错误的端口，%Port% 大于所设置的范围，请在"1-65535"内。
%ing% && goto:RemotePort)
:Password
cls
echo 当前修改 Administrator 用户密码
set /p pwd1=请输入密码：
cls
set /p pwd2=请再次输入密码：
if "%pwd1%"=="%pwd2%" (
net user Administrator %pwd2% > nul
echo 修改成功，请牢记你的密码。
%ing% && goto:Menu)else (echo 密码错误，请重新输入。
%ing% && goto:Password)
:Restart
shutdown.exe /r /f /t 0

脚本有 3 个选项：

1、修改远程端口。

脚本除了修改 3389 端口，还会添加修改的远程端口到防火墙中放行；

2、修改 administrator 的登录密码。

3、重启计算机。

未经允许不得转载：搬瓦工VPS_美国VPS » Windows服务器/VPS教程：如何修改3389端口来升级安全性能